Получить консультацию

Как в 1С сформировать документ Word?

В данной статье рассмотрим достаточно простой и удобный способ формирования документов Word из 1С. Сама по себе 1С формировать документы Word “не умеет”, и для работы с такими документами используется собственно MS Word. Поэтому вначале нужно определенным образом подготовить документ, а после загрузить его в макет двоичных данных в 1С.
Для корректной работы данного способа необходимо, чтобы на компьютере, где происходит формирование документа, был установлен MS Office. Также, документ формируется на клиенте, с тем чтобы вывести его на экран пользователю. Но возможно формирование и на сервере, если на сервере установлен Word – например, для прикрепления файлов к справочникам.

Подготовка шаблона Word

В документе Word можно вставлять поля специального типа DocVariables. Это можно сделать либо вставив соответствующий фрагмент текста, либо через графический интерфейс. На примере Word 2016, это делается через меню Вставка / Экспресс блоки/ Поле. В списке доступных полей нас интересует DocVariable. Указываем нужное имя и жмем ОК.

1С напечатать Word DocVariables

Для скрытия / отображения кодов полей в документе, жмем Alt + F9. Для экономии времени, можно просто копировать нужные поля и вставлять в нужные места документа. Чтобы создать новую переменную документа, достаточно просто в кавычках заменить имя.

1С сформировать Word

Формирование документа Word из 1С

После того, как шаблон готов, его нужно загрузить в виде макета с типом “Двоичные данные”. Это можно сделать в обработке, в общем макете, в справочнике и т.д. Рассмотрим на примере хранения макета в обработке.

Сперва нужно создать ComОбъект Word, сохранить файл из макета во временный файл, и прочитать его в Word. Далее мы переходим к заполнению переменных DocVariablе любым удобным способом – можно явно указывать нужные имена переменных и их значения, а можно заранее подготовить структуру данных и в цикле заполнить по этой структуре. Далее необходимо обновить поля в документе Word, скрыть коды полей, если вдруг они включены, и отобразить документ. Для доступа к конкретному полю DocVariable используется код  вида ComОбъектWord.Variables(“СтроковоеИмяПеременной”).Value. Делаем это в попытке, на случай, если поля с таким именем в Word нет.

&НаКлиенте
Процедура ВывестиДокументWord(Команда)
	МакетШаблонWord = ПолучитьМакетНаСервере();	
	ОбъектWord = Новый COMОбъект("Word.Application");	
	ИмяВременногоФайла = ПолучитьИмяВременногоФайла();
	МакетШаблонWord.Записать(ИмяВременногоФайла);
	ДокументWord = ОбъектWord.Documents.Add(ИмяВременногоФайла);	
	//Удобнее всего заполнять через структуру
	СтруктураДанных = Новый структура("ДатаДокумента, ТекстИз1С", Формат(ТекущаяДата(),"ДЛФ=DD"), "Какой-то текст из 1С");
	Для Каждого КлючИЗначение Из СтруктураДанных Цикл
		Попытка 
			ДокументWord.Variables(КлючИЗначение.Ключ).Value = КлючИЗначение.Значение;
		Исключение
		КонецПопытки;
	КонецЦикла;
	
	ДокументWord.Fields.Update();
	ОбъектWord.ActiveWindow.View.ShowFieldCodes = False;
	ОбъектWord.Visible = True;	
КонецПроцедуры

&НаСервере
Функция ПолучитьМакетНаСервере()
	
	Возврат РеквизитФормыВЗначение("Объект").ПолучитьМакет("Макет");
	
КонецФункции

Оставьте комментарий

Ваш адрес email не будет опубликован. Обязательные поля помечены *

два × один =

К НАЧАЛУ